Blackout/build.gradle

import java.nio.charset.StandardCharsets

plugins {
    id "java"
    id "maven-publish"
    id "net.minecrell.plugin-yml.bukkit" version "0.6.1-SNAPSHOT"
    id "com.github.johnrengelman.shadow" version "7.1.2"
    id "io.papermc.paperweight.userdev" version "1.3.5"
}

repositories {
    maven {
        url = uri("https://papermc.io/repo/repository/maven-public/")
    }

    maven {
        url = uri("https://repository.apache.org/content/repositories/snapshots/")
    }

    maven {
        url = uri("https://repo.maven.apache.org/maven2/")
    }
    mavenCentral()
}

def paperVersion = "1.17.1"

dependencies {
    paperweightDevelopmentBundle("io.papermc.paper:dev-bundle:${paperVersion}-R0.1-SNAPSHOT")
    library("org.json:json:20220320")
    library("org.projectlombok:lombok:1.18.22")
    annotationProcessor("org.projectlombok:lombok:1.18.22")
}

group = "dev.plex"
version = "0.1-SNAPSHOT"
description = "Blackout exploits on your Minecraft server."

bukkit {
    name = "Blackout"
    version = rootProject.version
    description = rootProject.description
    main = "dev.plex.Blackout"
    website = "https://plex.us.org"
    authors = ["Telesphoreo", "Taah"]
    apiVersion = "1.17"
}

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(17))
}

publishing {
    publications {
        maven(MavenPublication) {
            from(components.java)
        }
    }
}

tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

reobfJar {
    setArchivesBaseName("Blackout-${paperVersion}")
}

tasks {
    build {
        dependsOn(reobfJar)
    }

    javadoc {
        options.memberLevel = JavadocMemberLevel.PRIVATE
    }
    assemble {
        dependsOn(reobfJar)
    }

    compileJava {
        options.encoding = StandardCharsets.UTF_8.name()
        options.release.set(17)
    }
    processResources {
        filteringCharset = StandardCharsets.UTF_8.name()
    }
}