mirror of
https://github.com/reactos/reactos.git
synced 2024-09-12 05:43:24 +00:00
![Amine Khaldi](/assets/img/avatar_default.png)
* Create a branch for some evul shell experiments. svn path=/branches/shell-experiments/; revision=61927
110 lines
2.3 KiB
PHP
110 lines
2.3 KiB
PHP
|
|
#ifdef _M_IX86
|
|
#define KUSER_SHARED_SYSCALL HEX(7ffe0300)
|
|
#define KGDT_R0_CODE 8
|
|
MACRO(STUBCODE_U, Name, SyscallId, ArgCount)
|
|
StackBytes = 4 * ArgCount
|
|
FPO 0, 0, 0, 0, 0, FRAME_FPO
|
|
mov eax, SyscallId
|
|
mov ecx, KUSER_SHARED_SYSCALL
|
|
call dword ptr [ecx]
|
|
ret StackBytes
|
|
ENDM
|
|
MACRO(STUBCODE_K, Name, SyscallId, ArgCount)
|
|
StackBytes = 4 * &ArgCount
|
|
FPO 0, 0, 0, 0, 0, FRAME_FPO
|
|
mov eax, SyscallId
|
|
lea edx, [esp + 4]
|
|
pushfd
|
|
push KGDT_R0_CODE
|
|
call _KiSystemService
|
|
ret StackBytes
|
|
ENDM
|
|
#elif defined(_M_AMD64)
|
|
MACRO(STUBCODE_U, Name, SyscallId, ArgCount)
|
|
.ENDPROLOG
|
|
mov eax, SyscallId
|
|
mov r10, rcx
|
|
syscall
|
|
ret
|
|
ENDM
|
|
MACRO(STUBCODE_K, Name, SyscallId, ArgCount)
|
|
.ENDPROLOG
|
|
EXTERN Nt&Name:PROC
|
|
lea rax, Nt&Name[rip]
|
|
mov r10, ArgCount * 8
|
|
jmp KiZwSystemService
|
|
ENDM
|
|
#elif defined(_M_ARM)
|
|
MACRO(STUBCODE_U, Name, SyscallId, ArgCount)
|
|
swi #SyscallId
|
|
bx lr
|
|
ENDM
|
|
MACRO(STUBCODE_K, Name, SyscallId, ArgCount)
|
|
mov ip, lr
|
|
swi #SyscallId
|
|
bx ip
|
|
ENDM
|
|
#elif defined(_M_PPC)
|
|
MACRO(STUBCODE_U, Name, SyscallId, ArgCount)
|
|
stwu 1,-16(1)
|
|
mflr 0
|
|
stw 0,0(1)
|
|
li 0, SyscallId
|
|
sc
|
|
lwz 0,0(1)
|
|
mtlr 0
|
|
addi 1,1,16
|
|
blr
|
|
ENDM
|
|
#define STUBCODE_K STUBCODE_U
|
|
#elif defined(_M_MIPS)
|
|
MACRO(STUBCODE_U, Name, SyscallId, ArgCount)
|
|
li $8, KUSER_SHARED_SYSCALL
|
|
lw $8,0($8)
|
|
j $8
|
|
nop
|
|
ENDM
|
|
MACRO(STUBCODE_K, Name, SyscallId, ArgCount)
|
|
j KiSystemService
|
|
nop
|
|
ENDM
|
|
#else
|
|
#error unsupported architecture
|
|
#endif
|
|
|
|
#ifdef _M_IX86
|
|
MACRO(MAKE_LABEL, Name, StackBytes)
|
|
PUBLIC _&Name&@&StackBytes
|
|
_&Name&@&StackBytes:
|
|
ENDM
|
|
MACRO(START_PROC, Name, StackBytes)
|
|
PUBLIC _&Name&@&StackBytes
|
|
.PROC _&Name&@&StackBytes
|
|
ENDM
|
|
#else
|
|
MACRO(MAKE_LABEL, Name, StackBytes)
|
|
PUBLIC &Name
|
|
&Name:
|
|
ENDM
|
|
MACRO(START_PROC, Name, StackBytes)
|
|
PUBLIC &Name
|
|
.PROC &Name
|
|
ENDM
|
|
#endif
|
|
|
|
MACRO(STUB_U, Name, ArgCount)
|
|
MAKE_LABEL Zw&Name, %ArgCount * 4
|
|
START_PROC Nt&Name, %ArgCount * 4
|
|
STUBCODE_U Name, SyscallId, %ArgCount
|
|
.ENDP
|
|
SyscallId = SyscallId + 1
|
|
ENDM
|
|
|
|
MACRO(STUB_K, Name, ArgCount)
|
|
START_PROC Zw&Name, %ArgCount * 4
|
|
STUBCODE_K Name, SyscallId, %ArgCount
|
|
.ENDP
|
|
SyscallId = SyscallId + 1
|
|
ENDM
|